Macro's are VERY important

I took most of this pages information from the Wow Forums from a mage named Zarakaar he's a Level 70 mage and has made a really good guide for macros post on the forum located here This is an important thing for mages to understand. It can literally save your butt when you are in need of a spell to turn the tide in combat against your foe.

Sources & Resources

Those new to using macros (or programming in general) would benefit from a read through Cogwheelâ??s Macro Intro & FAQ at http://forums.worldofwarcraft.com/thread.html?topicId=96143900&sid=1

Those with some experience or a deeper interest in coding macros might enjoy Neuroâ??s Guide to Macro Options (v4) at http://forums.worldofwarcraft.com/thread.html?topicId=102812453&sid=1

Another great resource for macro, addon, and script information of all sorts is http://www.wowwiki.com

Information and ideas included in this guide have also been taken from the following sites.
My thanks are due to these authors and contributors.

http://forums.worldofwarcraft.com/thread.html?topicId=12021348&sid=1
http://forums.wow-europe.com/thread.html?topicId=93909906&sid=1
http://wow-en.curse-gaming.com/wiki/mage-macro-guide/
http://magewiki.wikispaces.com/Macros

Offensive Macro's

The classic Presence of Mind, Arcane Power, and trinket macro.

/cast Presence of Mind
/stopcasting
/cast Arcane Power
/stopcasting
/use Vengeance of the Illidari
/stopcasting
/cast Pyroblast


I use a variation on this myself for this macro I like to hit the keyboard a few times to ratchet up the sequence.

#showtooltip pyroblast
/use (whatever your trinket is)
/stopcasting
/castsequence reset=combat/target Arcane Power, Presence of Mind, Pyroblast


Pet Tricks: the Water Elemental and you.
Spammable Summon & Attack – This will summon your pet, and if pressed again, will set it to attack your target ones the lag on summoning finishes. Spamming is okay, and won’t cause your pet’s first waterbolt to cancel and restart.

/cast [nopet] Summon Water Elemental
/stopmacro [target=pettarget, exists]
/petattack


Interrupt Ice Lance
Mostly for Frostbite mages, this macro stops whatever spell you were casting and casts Ice Lance.

/stopcasting
/cast Ice Lance

Summon & Freeze – Summons or activates the ranged frost nova power, Freeze. Using normal cast commands has been unreliable for this power.


/cast [nopet] Summon Water Elemental
/stopmacro [nopet]
/click PetActionButton5


Dismiss (& Invisibility) – You can use this script to dismiss your pet without using the pet dropdown menu. This particular macro dismisses him and begins your Invisibility fade, so he won't force you into combat unintentionally.

/script PetAbandon()
/cast Invisibility

# Castsequence Attack Routine
This is a cast sequence designed for mana efficiency - three Scorches and an Arcane Blast. It will reset to Arcane Blast if not pressed for 7 seconds (at least enough time for the debuff to begin to fade).

/castsequence reset=7 Arcane Blast, Scorch, Scorch, Scorch


# Friendly Fire Targeting
Replacing spells with this macro will cause you to cast them at your target’s target if you’re targeting a unit which cannot be attacked.

/cast [harm] [target=targettarget] Fireball


# Cooldown Burners
Automatically casting spells or using trinkets whenever they are cooled down can still be done, if the spells don’t cause a global cooldown when activated. However, any time the trinket or spell is not ready, error text is displayed, error speech is triggered, and the “spell failed” sound effect is played. More complex scripts can remove the text, but I have not found a way to remove the failure sound. Regardless, here are two such macros.

/use Zandalarian Hero Charm
/stopcasting
/cast Fireball


/cast Combustion
/stopcasting
/cast Fireball

Defensive Macros

Blink & Look
Stops any cast or channel and Blinks you forward instead. Then, if your target is an enemy, flips your camera angle 180 degrees. Macroes cannot turn your character, only the camera, so a two-button mouse move will be needed to face your attacker again.
/stopcasting
/cast Blink
/stopmacro [noharm]
/script FlipCameraYaw(180)


Decurse
A reasonable replacement for the defunct decursive addon, hitting this button will remove a curse from whoever’s unit frame or 3D figure your cursor is hovering over. If your mouse is over a hostile or no target, you’ll decurse yourself.

/cast [target=mouseover, help] [target=player] Remove Lesser Curse


Interrupt Counterspell
Stops what you’re casting to immediately cast Counterspell.

/stopcasting
/cast Counterspell


Focus Counterspell
Uses the Alt modifier to CS your focus, rather than your target. Found this one very useful for bosses who need to be interrupted while DPSing elsewhere.

/cast [modifier:Alt, target=focus, exists, nodead] [] Counterspell


Your Favorite Harmless Animal, Polymorph
Polymorph: Focus – Sets your focus to your target and polymorphs it with a left click. Sheeps your focus without changing targets if you right click.

/cast [button:2, target=focus] [] Polymorph
/focus [nobutton:2]


Polymorph: Spam – Casts Detect Magic, sets the Star raid icon, sets your focus, and announces to your party or raid group your intention to sheep the target. How’s that for a chat spamming polymorph announcement?

/cast detect magic
/focus
/script SetRaidTarget("focus", 1)
/script if UnitSex("target")==1 then g="female " else g="male " end;s="I'm going to sheep a "..g..UnitLevel("target").." %T";c="Party";if GetNumRaidMembers()>0 then c="raid" end;SendChatMessage(s,c)


Polymorph: Random – This macro randomly chooses the harmless animal your enemy will some impersonate.

/castrandom Polymorph, Polymorph: Pig, Polymorph: Turtle


Polymorph: Target Alert - This script will whisper any member of your party who is targetting your target. Click it before or while sheeping to help clear things up.

/script u=UnitIsUnit;c="Party";t="Target";for i=0,40 do if not u(c..i,"player") then if u(c..i..t,t) then n,r=UnitName(c..i) SendChatMessage("I am Polymorphing your target!","WHISPER",this.language,n) end end end

Shapeshifting, Ice Cube Form
Breakable Ice Block – A 1.5 second “dead time” on toggle buttons like Ice Block was implemented to prevent unintentionally canceling buffs by spamming. This macro will restore previous functionality so Ice Block can be used to cancel debuffs almost instantaneously.

/cancelaura Ice Block
/cast Ice Block


Ice Block/Cold Snap – A macro allows rapid recasting of Ice Block by incorporating Cold Snap. The reset should be changed to 240 for Ice Floes.

/cancelaura Ice Block
/castsequence reset=300 Ice Block, Cold Snap


Break & Counterspell – This breaks Ice Block and immediately Counterspells your target.

/cancelaura Ice Block
/cast Counterspell


Break’n’Blink – This breaks Ice Block and immediately Blinks you forward.

/cancelaura Ice Block
/cast Blink


One-Button Wards
Left click for Fire Ward, right click for Frost Ward

/cast [button:2] Frost Ward; Fire Ward


Ice Barrier & Mana Shield
This cast sequence will use a single button to cast Ice Barrier, then Mana Shield. If only Ice Barrier is cast, it will reset to Ice Barrier again in 30 seconds (reset should be changed to 24 for Ice Floes). The problem is, this isn’t a real cooldown test, it’s just a counter from the previous button push. Casting Mana Shield will move the sequence back to Ice Barrier, even if it is not yet ready. Adding another Mana Shield to the sequence would stop the pseudo-cooldown timing, by not pushing to Ice Barrier until 30 seconds after the Last mana shield cast.

/castsequence reset=30 Ice Barrier, Mana Shield


Self-Bandaging – Although this one doesn’t actually involve a mage spell, it is extremely useful. If your target can be healed, you bandage it, otherwise you bandage yourself (without losing your target).

/use [help] [target=player] Heavy Netherweave Bandage

Super Polymorph Macro

Thought I'd throw this super Sheep Macro out there for you guys. Its your basic focus sheep macro with some nice additions for dealing with party members who have been mind controled and an option to instant cast your sheep if you have the prescense of mind talent (and you press ctrl).

With all Focus Sheep Macros I highly highly highly recommend having the Focus Frame addon (if your not using xperl or someother unit frames that does the same thing). Also When you create it I highly recommend using the red ? mark icon as this way the macro will appear exactly as your sheep spell on your bar. I put together an indepth article about Focus Frame and using Focus Macros in our forums here.

#showtooltip
/cast [mod:ctrl]presence of mind
/cast [target=party1,harm][target=party2,harm][target=party3,harm][target=party4,harm][target=focus,harm,nodead,nomod:shift] Polymorph
/clearfocus [mod:shift][target=focus,dead]
/focus [target=target,noexists]
What it does and how it works:
when you press the button to activate the macro it attempts to do the following things in order and does the first one it can...
1. Checks to see if any of your party members are hostile (ie under a Mind Control Debuff) and sheeps them if they are.
2. Sheeps your focus target if you have one and its hostile and not dead.
3. Sheeps your current target and makes it your focus target so that the next time you activate the macro it sheeps your focus and not your current target.

Resetting the Macro for new Targets or if you current Sheep is dead: If you have a focus target already but want to sheep a different enemy instead just hold shift and it will cast it on your current target and establish it as your focus from then on. If your focus is dead, the macro automatically clears your focus and picks up your current target as the new focus for sheeping.

Instant Cast via Ctrl: if you have the prescense of mind talent and you press ctrl it burns your PoM and makes that sheep cast instant.


Making modifications to this Macro:
You can tweak this macro for you own ends. If you want to change the ctrl and shift modifier keys to be something else just change the [mod:ctrl] [mod:shift] nomod:shift to [mod:alt] [mod:ctrl] [mod:shift] and [nomod:alt] [nomod:ctrl] [nomod:shift] respectively. If you want to change the sheep to be pig or turtle you can by changing Polymorph to Polymorph: Pig or Polymorph: Turtle. However marcos only allow you 255 characters to work with (macro as written is 250 characters). You can generally do so by removing either /cast [mod:ctrl]presence of mind if you don't have the PoM talent, or #showtooltip and changing the icon to something besides the red ? mark.

#showtooltip
/cast [mod:ctrl]presence of mind
/cast [target=party1,harm][target=party2,harm][target=party3,harm][target=party4,harm][target=focus,harm,nodead,nomod:shift] Polymorph
/clearfocus [mod:shift][target=focus,dead]
/focus [target=target,noexist]

Utility Macros

Mana Gems
This macro sequentially conjures all your mana gems on right clicks, and uses the highest level one available on left click. As a fall-through macro, this will cause error messages when used to consume gems.

/castsequence [button:2] reset=120 Conjure Mana Emerald, Conjure Mana Ruby, Conjure Mana Citrine, Conjure Mana Jade, Conjure Mana Agate;
/stopmacro [button:2]
/use Mana Emerald
/use Mana Ruby
/use Mana Citrine
/use Mana Jade
/use Mana Agate


Evocation
First two clicks equip your spirit weapons, third click casts Evocation. Right clicking puts back on DPS weaponry.

/castsequence [button:1] reset=10 Serpentcrest Life-Staff, Marli's Touch, Evocation;
/stopmacro [button:1]
/equip Time-Shifted Dagger
/equip The Saga of Terokk
/equip Nether-Core's Control Rod


Food & Water – This macro has you eat and drink with a click, conjure water with shift-click, and conjure food with shift-right-click.

/use [nomodifier] Conjured Glacier Water
/use [nomodifier] Conjured Croissant
/cast [modifier:shift, button:2] Conjure Food;[modifier:shift] Conjure Water


Smart Dampen/Amplify
Left clicks Dampen Magic, right clicks Amplify; if your target is in your party, it buffs him, otherwise it buffs you instead.

/cast [button:2, party] [button:2, target=player] Amplify Magic;[party] [target=player] Dampen Magic
Self Buff Sequence
Insert your own favorite soloing buffs, and press one button three times to cast them.

/castsequence [target=player] reset=600 Dampen Magic, Arcane Intellect, Molten Armor;


One-Button Armor
Click for Mage Armor, right click for Molten Armor, alt-click for Ice Armor.

/cast [modifier:alt]Ice Armor; [button:2]Molten Armor; Mage Armor


One-Button Portal
Useful for those below level 65 to get around and help their friends get around. Click to portal to Ironforge (Orgrimmar), alt for Stormwind (Undercity), control for Darnassus (Thunder Bluff), and shift for Exodar (Silvermoon).

/cast [modifier:shift] Portal: Exodar; [modifier:alt] Portal: Stormwind; [modifier:ctrl] Portal: Darnassus; Portal: Ironforge

/cast [modifier:shift] Portal: Silvermoon; [modifier:alt] Portal: Undercity; [modifier:ctrl] Portal: Thunder Bluff; Portal: Orgrimmar


One-Button Teleport
Here’s the same thing as the Portal macro, but just for you. It’s not useful past level 59.

/cast [modifier:shift] Teleport: Exodar; [modifier:alt] Teleport: Stormwind; [modifier:ctrl] Teleport: Darnassus; Teleport: Ironforge

/cast [modifier:shift] Teleport: Silvermoon; [modifier:alt] Teleport: Undercity; [modifier:ctrl] Teleport: Thunder Bluff; Teleport: Orgrimmar

High Level Portal & Teleport
Once you’re level 65, this will get you anywhere. Click for portal, right click for teleport. This one’s even the same for Horde and Alliance.

/cast [button:2] Teleport: Shattrath; Portal: Shattrath
Total visists: 12565